Covadis - Applicatif Topographie / VRD d'Autocad

Forum - Communauté - Entraide
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  

Partagez | 
 

 Tracé de voie ferrée (fonction raccord)

Voir le sujet précédent Voir le sujet suivant Aller en bas 
AuteurMessage
crashray
Utilisateur averti
Utilisateur averti
avatar

Nombre de messages : 42
Date d'inscription : 11/08/2010

MessageSujet: Tracé de voie ferrée (fonction raccord)   Mer 13 Avr - 9:50

Bonjour,
Je travaille dans le voie ferrée. Nous avons des rayons minimums à respecter (R=150m) pour faire un tracé. Actuellement, je trace mes lignes droites et après j'utilise la fonction Raccord en ajoutant l'option Rayon pour rentrer le rayon souhaité.
J'ai plusieurs questions à ce propos :
1) Y a t'il une fonction pour "maximiser" ce rayon ? En voie ferrée, plus le rayon est grand, mieux c'est. Actuellement, je tatonne jusqu'à avoir le message 'Le rayon est trop large'
2) Peut-on définir un bout de ligne droite minimum sur lequel l'arc de rayon ne peut venir entamer ? Ce sont des règles de tracé. Par exemple il me faut 10ml en ligne droit avant un rayon de 150 et pareil de l'autre côté. Donc je voudrais pouvoir tracé mes 2 lignes, lui dire jusqu'où l'arc peut aller et qu'il me maximise mon rayon.
3) Plus compliqué : On peut quand on tourne passer d'un rayon de 150 à un rayon de 200 pour revenir à un rayon de 150. Comment faire ça sous autocad/covadis pour respecter les tangentes ?

Merci pour votre aide.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
titai07
Utilisateur confirmé
Utilisateur confirmé


Nombre de messages : 936
Age : 49
Localisation : Rhones Alpes,mais surtout un peu partout
Emploi : Formateur
Date d'inscription : 01/01/2007

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Mer 13 Avr - 13:10

Bonjour,

sur qu'elle version de COVADIS ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
crashray
Utilisateur averti
Utilisateur averti
avatar

Nombre de messages : 42
Date d'inscription : 11/08/2010

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Mer 13 Avr - 13:57

11.0e mais j'ai la mise à jour à installer.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
titai07
Utilisateur confirmé
Utilisateur confirmé


Nombre de messages : 936
Age : 49
Localisation : Rhones Alpes,mais surtout un peu partout
Emploi : Formateur
Date d'inscription : 01/01/2007

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Mer 13 Avr - 16:13

Fait la mise en jour en V12 et reviens à l'assaut

cordialement
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
crashray
Utilisateur averti
Utilisateur averti
avatar

Nombre de messages : 42
Date d'inscription : 11/08/2010

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Mer 14 Nov - 23:38

Juste pour info, j'ai trouvé réponse à ma question ici.
Voilà le lisp :
Code:
(defun z_dir (p1 p2 / )
  (trans
    '(0.0 1.0 0.0)
    (mapcar
      '(lambda (k)
        (/ k
          (sqrt
            (apply '+
              (mapcar
                '(lambda (x) (* x x))
                (mapcar '- p2 p1)
              )
            )
          )
        )
      )
      (mapcar '- p2 p1)
    )
    0
  )
)
(defun ang_x (px p1 p2 / l_pt l_d p ang)
  (setq
    l_pt (mapcar '(lambda (x) (list (car x) (cadr x) (caddr x))) (list px p1 p2))
    l_d (mapcar 'distance l_pt (append (cdr l_pt) (list (car l_pt))))
    p (/ (apply '+ l_d) 2.0)
    ang (* (atan (sqrt (/ (* (- p (car l_d)) (- p (caddr l_d))) (* p (- p (cadr l_d)))))) 2.0)
  )
)
(defun det_wh (px p1 p2 / v1 v2 det_or)
  (setq
    v1 (mapcar '- p2 p1)
    v2 (mapcar '- px p1)
  )
  (if (> (apply '(lambda (x1 y1 z1 x2 y2 z2) (- (* x1 y2) (* y1 x2))) (append v1 v2)) 0.0) 1 -1)
)
(defun k_th (p1 p2 c / k)
  (setq k (/ c (distance p1 p2)))
  (mapcar '+ (mapcar '* (mapcar '- p2 p1) (list k k k)) p1)
)
(defun c:my_filletrad ( / js1 js2 ps1 ps2 pt_lst pt l3 min_dist min_pt snd_pt alpha chord p_o a1 a2)
  (princ "\nSélectionnez la première ligne: ")
  (while (or (null (setq js1 (entsel))) (/= (cdr (assoc 0 (entget (car js1)))) "LINE")))
  (princ "\nSélectionnez la deuxième ligne: ")
  (while (or (null (setq js2 (entsel))) (/= (cdr (assoc 0 (entget (car js2)))) "LINE")))
  (setq
    ps1 (trans (cadr js1) 1 0)
    ps2 (trans (cadr js2) 1 0)
    js1 (entget (car js1))
    js2 (entget (car js2))
    pt_lst (list (cdr (assoc 10 js1)) (cdr (assoc 11 js1)) (cdr (assoc 10 js2)) (cdr (assoc 11 js2)))
    pt (inters (car pt_lst) (cadr pt_lst) (caddr pt_lst) (cadddr pt_lst) nil)
  )
  (cond
    (pt
      (if (eq (det_wh (cadddr pt_lst) (car pt_lst) (cadr pt_lst)) (det_wh (caddr pt_lst) (car pt_lst) (cadr pt_lst)))
        (if (> (distance pt (caddr pt_lst)) (distance pt (cadddr pt_lst)))
          (setq l3 (list pt (caddr pt_lst)))
          (setq l3 (list pt (cadddr pt_lst)))
        )
        (if (eq (det_wh ps2 (car pt_lst) (cadr pt_lst)) (det_wh (caddr pt_lst) (car pt_lst) (cadr pt_lst)))
          (setq l3 (list pt (caddr pt_lst)))
          (setq l3 (list pt (cadddr pt_lst)))
        )
      )
      (if (eq (det_wh (cadr pt_lst) (caddr pt_lst) (cadddr pt_lst)) (det_wh (car pt_lst) (caddr pt_lst) (cadddr pt_lst)))
        (if (> (distance pt (car pt_lst)) (distance pt (cadr pt_lst)))
          (setq l3 (cons (car pt_lst) l3))
          (setq l3 (cons (cadr pt_lst) l3))
        )
        (if (eq (det_wh ps1 (caddr pt_lst) (cadddr pt_lst)) (det_wh (car pt_lst) (caddr pt_lst) (cadddr pt_lst)))
          (setq l3 (cons (car pt_lst) l3))
          (setq l3 (cons (cadr pt_lst) l3))
        )
      )
      (setq min_dist (getreal "\nDistance mini à respecter? <10.0>: "))
      (if (not min_dist) (setq min_dist 10.0))
      (setq
        min_pt (polar (car l3) (angle (car l3) (cadr l3)) min_dist)
        snd_pt (polar (cadr l3) (angle (cadr l3) (caddr l3)) (distance (cadr l3) min_pt))
      )
      (setvar "FILLETRAD"
        (distance
          (inters
            min_pt (polar min_pt (+ (angle (car l3) (cadr l3)) (* pi 0.5)) (distance (cadr l3) min_pt))
            snd_pt (polar snd_pt (+ (angle (cadr l3) (caddr l3)) (* pi 0.5)) (distance (cadr l3) min_pt))
            nil
          )
          min_pt
        )
      )
      (setq
        alpha (ang_x (cadr l3) (car l3) (caddr l3))
        l_tg (* (getvar "FILLETRAD") (/ 1.0 (/ (sin (* alpha 0.5)) (cos (* alpha 0.5)))))
        js1 (subst (cons 10 (car l3)) (assoc 10 js1) js1)
        js2 (subst (cons 10 (caddr l3)) (assoc 10 js2) js2)
      )
      (entmod ; mettre juste entmod en rem pour ne pas ajuster
        (setq js1 (subst (cons 11 (k_th pt (car l3) l_tg)) (assoc 11 js1) js1))
      )
      (entmod ; mettre juste entmod en rem pour ne pas ajuster
        (setq js2 (subst (cons 11 (k_th pt (caddr l3) l_tg))  (assoc 11 js2) js2))
      )
      (setq
        p_o (k_th pt (mapcar '* (mapcar '+ (cdr (assoc 11 js1)) (cdr (assoc 11 js2))) '(0.5 0.5 0.5)) (+ (getvar "FILLETRAD") (* (getvar "FILLETRAD") (1- (/ 1.0 (sin (* alpha 0.5)))))))
        a1 (angle p_o (cdr (assoc 11 js1)))
        a2 (angle p_o (cdr (assoc 11 js2)))
        dxf_210 (z_dir p_o (cdr (assoc 11 js1)))
      )
      (entmake
        (list
          (cons 0 "ARC")
          (cons 100 "AcDbEntity")
          (assoc 67 js1)
          (assoc 410 js1)
          (cons 8 (getvar "CLAYER"))
          (if (assoc 62 js1) (assoc 62 js1) (cons 62 256))
          (if (assoc 6 js1) (assoc 6 js1) (cons 6 "BYLAYER"))
          (cons 38 (+ (cadddr (assoc 10 js1)) (getvar "ELEVATION")))
          (cons 39 (getvar "THICKNESS"))
          (cons 100 "AcDbCircle")
          (cons 10 (trans p_o 0 dxf_210))
          (cons 40 (getvar "FILLETRAD"))
          (cons 210 dxf_210)
          (cons 100 "AcDbArc")
          (cons 50
            (if (equal (* (+ (max a1 a2) (min a1 a2)) 0.5) (angle p_o pt) 1E-8)
              (min a1 a2)
              (max a1 a2)
            )
          )
          (cons 51
            (if (equal (* (+ (max a1 a2) (min a1 a2)) 0.5) (angle p_o pt) 1E-8)
              (max a1 a2)
              (min a1 a2)
            )
          )
        )
      )
    )
    (T
      (princ "\nNe peut raccorder des lignes dans des plans différents!")
    )
  )
  (prin1)
)
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
lili2006
Utilisateur confirmé
Utilisateur confirmé
avatar

Nombre de messages : 1137
Age : 50
Localisation : Bordeaux
Emploi : Professeur de Génie Civil en BTS Géomètre Topographe et Travaux Publics
Date d'inscription : 18/03/2009

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Jeu 15 Nov - 0:03

Bonsoir à toutes et tous,

Je ne comprends pas pourquoi tu n'utilises pas covadis,...

As-tu envisagé des raccordements de types arc/clotoide/arc ?
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://genie-civil.bbactif.com/
crashray
Utilisateur averti
Utilisateur averti
avatar

Nombre de messages : 42
Date d'inscription : 11/08/2010

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Jeu 15 Nov - 15:53

Je suis tout prêt à utiliser Covadis mais il faudrait que je sache comment faire.
Si tu as une méthode pour réaliser la même chose, je suis intéressé.

Merci
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
lili2006
Utilisateur confirmé
Utilisateur confirmé
avatar

Nombre de messages : 1137
Age : 50
Localisation : Bordeaux
Emploi : Professeur de Génie Civil en BTS Géomètre Topographe et Travaux Publics
Date d'inscription : 18/03/2009

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Jeu 15 Nov - 17:28

Bonjour à toutes et tous,

As-tu les ouvrages de Géomédia ?

Si oui, regardes le module VRD "Projets Linéaires par PT",..
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://genie-civil.bbactif.com/
crashray
Utilisateur averti
Utilisateur averti
avatar

Nombre de messages : 42
Date d'inscription : 11/08/2010

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Ven 16 Nov - 10:15

lili2006 a écrit:
Bonjour à toutes et tous,

As-tu les ouvrages de Géomédia ?

Si oui, regardes le module VRD "Projets Linéaires par PT",..
J'ai la version 12 nommé Topographie et VRD. J'ai bien trouvé le chapitre en question XII Profil linéaire par profil type.
J'avoue ne très peu utilisé les bouquins covadis. Je les trouve vraiment pas pratique. Pas d'index, un immense sommaire, numéro de page bizarre.

Je vais y jeter un oeil. Merci pour l'indication en tout cas.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
lili2006
Utilisateur confirmé
Utilisateur confirmé
avatar

Nombre de messages : 1137
Age : 50
Localisation : Bordeaux
Emploi : Professeur de Génie Civil en BTS Géomètre Topographe et Travaux Publics
Date d'inscription : 18/03/2009

MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   Ven 16 Nov - 11:32

Bonjour à toutes et tous,

Je les trouve plutôt bien fait perso,..

La plupart des choses que je sais faire aujourd'hui c'est grace à ces docs,...

Certes, il faut connaitre le comportement de AutoCAD et un peu de 3D pour un apprentissage en solitaire,...

Les forums (dont celui-ci) me permettent d'éclaircir les points qui me paraisse sombre à un moment donné,...
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://genie-civil.bbactif.com/
Contenu sponsorisé




MessageSujet: Re: Tracé de voie ferrée (fonction raccord)   

Revenir en haut Aller en bas
 
Tracé de voie ferrée (fonction raccord)
Voir le sujet précédent Voir le sujet suivant Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Montrer les voies ferrées plus tôt ?
» Pb pour le choix de la voie
» Ligne d'occupation des trains comme dans la réalité
» Choix de la voie en gare
» Voie de Programmation pour profil de vitesse

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
Covadis - Applicatif Topographie / VRD d'Autocad :: Autocad - l'environnement de Covadis :: Discussion générale-
Sauter vers:  
Créer un forum | © phpBB | Forum gratuit d'entraide | Signaler un abus | Forum gratuit